Стартиране на EXE VB6

Искам да стартирам EXE от програма на vb6.
Ползвам Shell.
Проблема е че въшната програма се стартира асинхронно, а мен ми триабва резултат за да протължа. Ако цикля с DO-LOOP, за да чакам резултата, процесора скача на 100% и това много забавя работата на стартираното EXE.
В msnd пише, 4е външната програма по подразбиране се стартира асинхронно, но ништо няма по въпроса, как да се вика синхронно.
За vb.net знам, че си има добавен параметър (Boolean тип) с който точно това се задава.
Има ли някои идея?...

polzvai shellexecuteex

izpolzvaj win32 API, CreateProcess

eti ti primer ot MSDN:

Private Type STARTUPINFO
cb As Long
lpReserved As String
lpDesktop As String
lpTitle As String
dwX As Long
dwY As Long
dwXSize As Long
dwYSize As Long
dwXCountChars As Long
dwYCountChars As Long
dwFillAttribute As Long
dwFlags As Long
wShowWindow As Integer
cbReserved2 As Integer
lpReserved2 As Long
hStdInput As Long
hStdOutput As Long
hStdError As Long
End Type

Private Type PROCESS_INFORMATION
hProcess As Long
hThread As Long
dwProcessID As Long
dwThreadID As Long
End Type

Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal _
hHandle As Long, ByVal dwMilliseconds As Long) As Long

Private Declare Function CreateProcessA Lib "kernel32" (ByVal _
lpApplicationName As String, ByVal lpCommandLine As String, ByVal _
lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As String, _
lpStartupInfo As STARTUPINFO, lpProcessInformation As _
PROCESS_INFORMATION) As Long

Private Declare Function CloseHandle Lib "kernel32" _
(ByVal hObject As Long) As Long

Private Declare Function GetExitCodeProcess Lib "kernel32" _
(ByVal hProcess As Long, lpExitCode As Long) As Long

Private Const NORMAL_PRIORITY_CLASS = &H20&
Private Const INFINITE = -1&

Public Function ExecCmd(cmdline$)
Dim proc As PROCESS_INFORMATION
Dim start As STARTUPINFO

' Initialize the STARTUPINFO structure:
start.cb = Len(start)

' Start the shelled application:
ret& = CreateProcessA(vbNullString, cmdline$, 0&, 0&, 1&, _
NORMAL_PRIORITY_CLASS, 0&, vbNullString, start, proc)

' Wait for the shelled application to finish:
ret& = WaitForSingleObject(proc.hProcess, INFINITE)
Call GetExitCodeProcess(proc.hProcess, ret&)
Call CloseHandle(proc.hThread)
Call CloseHandle(proc.hProcess)
ExecCmd = ret&
End Function

Sub Form_Click()
Dim retval As Long
retval = ExecCmd("notepad.exe")
MsgBox "Process Finished, Exit Code " & retval
End Sub

blagodaria za otgovorite:)

i az otkrih neshti4ko:

'*************************************************
'Reference=Windows Script Host Object Model (wshom.ocx)
'*************************************************

Private Sub Command1_Click()
Dim o As IWshRuntimeLibrary.WshShell

Set o = New IWshRuntimeLibrary.WshShell
With o
.Run "strEXEName", , -1
End With
Set o = Nothing
End Sub