Mixy, благодаря за идеята !

След извесна заигравка се получи следното:

procedure DrawColumnCellMatchText(const MatchText: String; MatchTextColor, MatchTextBkColor: TColor;

  Grid: TDBGrid; const CellRect: TRect; DataCol: Integer; Column: TColumn; State: TGridDrawState);

var

  Value: string;

  TextLeft: Integer;

  X: Integer;

  Txt: String;

  Offset: Integer;

  OldBrushColor, OldTextColor: TColor;

  B: TRect;



  procedure DrawTextBitmap(const txt: String; const BrushColor, TextColor: TColor);

  begin

    DrawBitmap.Canvas.Brush.Color := BrushColor;

    DrawBitmap.Canvas.Font.Color  := TextColor;

    DrawBitmap.Canvas.TextOut(TextLeft + X, 2, Txt);

    Inc(X, DrawBitmap.Canvas.TextWidth(Txt));

  end;



begin

  OldBrushColor := Grid.Canvas.Brush.Color;

  OldTextColor  := Grid.Canvas.Font.Color;



  Value := '';

  if Assigned(Column.Field) then

    Value := Column.Field.DisplayText;



  DrawBitmap.Canvas.Lock;

  try

    DrawBitmap.Canvas.Brush.Assign(Grid.Canvas.Brush);

    DrawBitmap.Canvas.Font.Color := Grid.Canvas.Font.Color;



    X := 0;

    DrawBitmap.Width := Max(DrawBitmap.Width, CellRect.Right - CellRect.Left);

    DrawBitmap.Height := Max(DrawBitmap.Height, CellRect.Bottom - CellRect.Top);

    B := Rect(0, 0, CellRect.Right - CellRect.Left, CellRect.Bottom - CellRect.Top);

    DrawBitmap.Canvas.FillRect(B);



    // TODO: BiDi mode

    case Column.Alignment of

      taLeftJustify:

        TextLeft := 2;

      taRightJustify:

        TextLeft := (CellRect.Right - CellRect.Left) - DrawBitmap.Canvas.TextWidth(Value) - 3;

    else { taCenter }

      TextLeft := ((CellRect.Right - CellRect.Left) shr 1) - (DrawBitmap.Canvas.TextWidth(Value) shr 1);

    end;



    Offset := Pos(MatchText, Value);

    while Offset > 0 do begin

      Txt := Copy(Value, 1, Offset - 1);

      if Txt <> '' then begin

        Delete(Value, 1, Length(Txt));

        DrawTextBitmap(Txt, OldBrushColor, OldTextColor);

      end;



      Txt := Copy(Value, 1, Length(MatchText));

      Delete(Value, 1, Length(Txt));

      DrawTextBitmap(Txt, MatchTextBkColor, MatchTextColor);



      Offset := Pos(MatchText, Value);

    end;

    if Value <> '' then

      DrawTextBitmap(Value, OldBrushColor, OldTextColor);



    Grid.Canvas.Brush.Style := bsClear;

    Grid.Canvas.CopyRect(CellRect, DrawBitmap.Canvas, B);

  finally

    DrawBitmap.Canvas.Unlock;

  end;

end;